Vector Fields: Streamline through a Point

Manipulate[
StreamPlot[field@@{x,y},{x,-3,3},{y,-3,3},StreamPoints->{{{u,Red},Automatic},1},ImageSize->{400,400}],
{{field,{Sin[3 #2]^3,Cos[3 #1]^3}&,"field"},
{{#1,#2}&->TraditionalForm@{x,y},
{#1,-#2}&->TraditionalForm@{x,-y},
{#2,-#1}&->TraditionalForm@{y,-x},
{#2,#1}&->TraditionalForm@{y,x},
{Cos[((#1)^2)+#2],1+#1-((#2)^2)}&->TraditionalForm@{Cos[(x^2)+y],1+x-(y^2)},
{1,Sin[#1^2+#2^2]}&->TraditionalForm@{1,Sin[(x^2)+(y^2)]},
{Cos[#2^2],Sin[#1^3]}&->TraditionalForm@{Cos[y^2],Sin[x^3]},
{1,Cos[#2^2+#1^3]}&->TraditionalForm@{1,Cos[y^2+x^3]},
{Sin[#1]^2+#2,Cos[#2^2+#1]}&->TraditionalForm@{Sin[x]^2+y,Cos[y^2+x]},
{Sin[Cos[3 #1]+3 #2],Cos[Sin[3 #2]+3 #1]}&->TraditionalForm@{Sin[Cos[3 x]+3 y],Cos[Sin[3 y]+3 x]},
{Sin[Cos[3 #2]+3 #1],Cos[Sin[3 #2]+3 #1]}&->TraditionalForm@{Sin[Cos[3 y]+3 x],Cos[Sin[3 y]+3 x]},
{Sin[Cos[3 #2]+Sin[3 #1]],3 Cos[Cos[3 #2]+3 #1]}&->TraditionalForm@{Sin[Cos[3 y]+Sin[3 x]],3 Cos[Cos[3 y]+3 x]},
{Sin[3 #2]^3,Cos[3 #1]^3}&->TraditionalForm@{Sin[3 y]^3,Cos[3 x]^3}},
PopupMenu},
{{u,{1,1}},{-3,-3},{3,3},Locator}]

Drag the locator; the red streamline then passes through that point, illustrating the flow of the vector field. The vector fields show rotations, sinks, sources, and saddle points.

Contributed by: Gosia Konwerska