Spherical Coordinates

Differential

f[ρ_,θ_,ϕ_]:={ρ Sin[ϕ]Cos[θ],ρ Sin[ϕ]Sin[θ],ρ Cos[ϕ]};
Manipulate[
If[reset,{dϕ,dθ,reset}={False,False,False}];
Show[
Graphics3D[{Line[{{0,0,0},{3,0,0}}],Line[{{0,0,0},{0,3,0}}],Line[{{0,0,0},{0,0,3}}]}],
(*shells*)SphericalPlot3D[{2,3},{ϕ,(π/6),(π/3)},{θ,(π/6),(π/4)}],
(*inside/outsides*)ParametricPlot3D[{f[ρ,θ,(π/6)],f[ρ,θ,(π/3)]},{ρ,2,3},{θ,(π/4),(π/6)}],
(*sides*)ParametricPlot3D[{f[ρ,(π/6),ϕ],f[ρ,(π/4),ϕ]},{ρ,2,3},{ϕ,(π/6),(π/3)}],
(*ϕ circle/arc*)If[dϕ,{ParametricPlot3D[{f[2,(π/4),ϕ]},{ϕ,0,((5π)/12)}],
Graphics3D[{Dashing[0.025],Line[{f[2,(π/4),(π/6)],{0,0,0},f[2,(π/4),(π/3)]}]}]},Graphics3D[{Point[{0,0,0}]}]],
(*θ circle/arc*)If[dθ,{ParametricPlot3D[{f[2 Sin[(π/6)],θ,(π/2)]},{θ,0,((5π)/12)}],
Graphics3D[{{Dashing[0.025],Line[{f[2 Sin[(π/6)],(π/6),(π/2)],{0,0,0},f[2 Sin[(π/6)],(π/4),(π/2)]}]},{Dashing[0.025],Line[{f[2,(π/4),(π/6)],f[2 Sin[(π/6)],(π/4),(π/2)]}]},{Dashing[0.025],Line[{f[2,(π/6),(π/6)],f[2 Sin[(π/6)],(π/6),(π/2)]}]}}]},Graphics3D[{Point[{0,0,0}]}]]
,Boxed->False,Ticks->None,Axes->None,PlotRange->{{0,3},{0,3},{0,3}}],
{{dϕ,False},{False,True}},
{{dθ,False},{False,True}},
Delimiter,
{{reset,False},{False,True}},
ControlPlacement->Left
]

Region in example 3

The region bounded in spherical coordinates between the spheres ρ=2, ρ=4, and the cone ϕ=(π/3);

Show[
Graphics3D[{Line[{{0,0,0},{4,0,0}}],Line[{{0,0,0},{0,4,0}}],Line[{{0,0,0},{0,0,5}}]}],
(*shells*)SphericalPlot3D[{2,4},{ϕ,0,(π/3)},{θ,(π/2),2π}],
(*cone*)ParametricPlot3D[{f[ρ,θ,(π/3)]},{ρ,2,4},{θ,(π/2),2π}],
(*end caps*)ParametricPlot3D[{f[ρ,0,ϕ],f[ρ,(π/2),ϕ]},{ρ,2,4},{ϕ,0,(π/3)}]
,Boxed->False,Ticks->None,Axes->None,PlotRange->{Automatic,Automatic,{0,5}}]